Grabbing Objects in Box2d « cocos2d for iPhone

cocos2d for iPhone » Programming » physics

Grabbing Objects in Box2d

(14 posts) (10 voices)

Started 1 year ago by mithril
Latest reply from iforce2d

Tags:

Box2D

mithril
Member

I'm new to box2d and am trying to let the user play around with objects (b2body's) on the screen using touch.

-(void)ccTouchesBegan:(NSSet *)touches withEvent:(UIEvent *)event {
	if (mouseJoint != NULL) return;
	UITouch *touch = [touches anyObject];
	CGPoint location = [touch locationInView:[touch view]];
	location = [[CCDirector sharedDirector] convertToGL:location];
	b2Vec2 locationInWorld = b2Vec2(location.x/PTM_RATIO, location.y/PTM_RATIO);

	//Iterate over the bodies in the physics world
	for (b2Body* b = world->GetBodyList(); b; b = b->GetNext())
	{
		for (b2Fixture* f = b->GetFixtureList(); f; f->GetNext()) {
			if (f->TestPoint(locationInWorld)) {
				b2MouseJointDef md;
				md.bodyA = groundBody;
				md.bodyB = b;
				md.target = locationInWorld;
				md.collideConnected = YES;
				md.maxForce = 1000.0f * b->GetMass();
				mouseJoint = (b2MouseJoint *)world->CreateJoint(&md);
				b->SetAwake(YES);

				return;
			}
		}
	}
}

-(void)ccTouchesMoved:(NSSet *)touches withEvent:(UIEvent *)event {
	if (mouseJoint == NULL) return;
	UITouch *touch = [touches anyObject];
	CGPoint location = [touch locationInView:[touch view]];
	location = [[CCDirector sharedDirector] convertToGL:location];
	b2Vec2 locationInWorld = b2Vec2(location.x/PTM_RATIO, location.y/PTM_RATIO);

	mouseJoint->SetTarget(locationInWorld);
}

-(void)ccTouchesCancelled:(NSSet *)touches withEvent:(UIEvent *)event {
	[self ccTouchesEnded:touches withEvent:event];
}

-(void)ccTouchesEnded:(NSSet *)touches withEvent:(UIEvent *)event {
	if (mouseJoint) {
		world->DestroyJoint(mouseJoint);
		mouseJoint = NULL;
	}
}

My app freezes when a touch is received. Any ideas?

Posted 1 year ago #

finder39
Member

not sure but check out RAy Wenderlich's breakout example

Posted 1 year ago #
mithril
Member

Hmm I used his example as a base but I wanted it to dynamically identify which bodies are being touched rather just testing for the paddle.

Posted 1 year ago #

robodude666
Member

This is what I found to work pretty well for dragging things around:

Have this somewhere in your interface:

b2Vec2 m_mouseWorld;
b2MouseJoint *m_mouseJoint;

I also defined this macro to make life easier:
#define ptm(__x__) (__x__/PTM_RATIO)

In your init method make sure to initialize the mouse joint:
m_mouseJoint = NULL;

And then the big blob of code that does it all:

- (void)ccTouchesBegan:(NSSet *)touches withEvent:(UIEvent *)event
{
	UITouch* myTouch = [touches anyObject];
	CGPoint location = [myTouch locationInView: [myTouch view]];
	location = [[CCDirector sharedDirector] convertToGL:location];
	location = [self convertToNodeSpace:location];

	m_mouseWorld.Set(ptm(location.x), ptm(location.y));
	if (m_mouseJoint != NULL)
	{
		return;
	}

	b2AABB aabb;
	b2Vec2 d = b2Vec2(0.001f, 0.001f);
	aabb.lowerBound = m_mouseWorld - d;
	aabb.upperBound = m_mouseWorld + d;

	// Query the world for overlapping shapes.
	QueryCallback callback(m_mouseWorld);
	world->QueryAABB(&callback, aabb);

	if (callback.m_fixture)
	{

		b2BodyDef bodyDef;
		b2Body* groundBody = world->CreateBody(&bodyDef);

		b2Body* bodyz = callback.m_fixture->GetBody();
		bodyz->SetAwake(true);

		b2MouseJointDef md;
		md.bodyA = groundBody;
		md.bodyB = bodyz;
		md.target = m_mouseWorld;
		md.maxForce = 1000.0f * bodyz->GetMass();

		m_mouseJoint = (b2MouseJoint*)world->CreateJoint(&md);
	}
}

- (void)ccTouchesMoved:(NSSet*)touches withEvent:(UIEvent*)event
{
	UITouch* myTouch = [touches anyObject];
	CGPoint location = [myTouch locationInView: [myTouch view]];
	location = [[CCDirector sharedDirector] convertToGL:location];
	location = [self convertToNodeSpace:location];

	m_mouseWorld.Set(ptm(location.x), ptm(location.y));

	if (m_mouseJoint)
	{
		m_mouseJoint->SetTarget(m_mouseWorld);
	}
}

- (void)ccTouchesEnded:(NSSet *)touches withEvent:(UIEvent *)event
{
	[self ccTouchesCancelled:touches withEvent:event];
}

- (void)ccTouchesCancelled:(NSSet *)touches withEvent:(UIEvent *)event {
	if (m_mouseJoint)
	{
		world->DestroyJoint(m_mouseJoint);
		m_mouseJoint = NULL;
	}
}

You will also need this file included as it's required for the query callback:

QueryCallback.h

#import "Box2D.h"

class QueryCallback : public b2QueryCallback
{
public:
	QueryCallback(const b2Vec2& point)
	{
		m_point = point;
		m_fixture = NULL;
	}

	bool ReportFixture(b2Fixture* fixture)
	{
		b2Body* body = fixture->GetBody();
		if (body->GetType() == b2_dynamicBody)
		{
			bool inside = fixture->TestPoint(m_point);
			if (inside)
			{
				m_fixture = fixture;

				// We are done, terminate the query.
				return false;
			}
		}

		// Continue the query.
		return true;
	}

	b2Vec2 m_point;
	b2Fixture* m_fixture;
};

Posted 1 year ago #

mithril
Member

Cool, I'll try this tomorrow and see how it works out.

One question though, I noticed you created groundBody as a filler for bodyA on each touch began. Don't you have to kill it/destroyBody on touch end? (Won't it stack up and eat memory on the device?)

Posted 1 year ago #
robodude666
Member

Probably. I only use this code to debug, so I don't exactly care (I know it's a bad thing, but still) about a memory leak here if I'm testing a quick thing. It's otherwise disabled with pre-processor conditions. In either case, Instruments never complained about it, so...

You can get away with creating the groundBody for bodyA in your init method and storing it as a member variable. That way it's only made once and it can be reused. The in your dealloc free up the memory.

-robodude666

Posted 1 year ago #
mithril
Member

Works perfectly. One other thing though.

RIght now if I grab an object it rotates freely. I would like to impose restrictions so it rotates up to + or - 45 degrees or so either way naturally (I don't want the object up side down). Is that possible?

I've tried angular damping but it only serves to slow down the rotation.

Posted 1 year ago #
matt
Member

Thanks for this!

Posted 1 year ago #
kyotchi
Member

Hi! I need some help about dragging sprites+box2d objects too.

I have tried the Mouse Joint way, and it works correct. However, I would like that the sprite moves exactly as the finger. I have read in the Box2d manual that it's better to use kinematic bodies in this case, but I don't know how to do it.

I have tried to set linear velocity but I can't give him the right angle and the body is just moving in the same direction and it can't stop.

Any ideas?

Thanks!

Posted 1 year ago #
renuka
Member

Hi,

I have tried above code and its not working can any one say me whats problem?

i have tried to debug code and getting error on this line.

world->QueryAABB(&callback, aabb);

Thanks,

Posted 1 year ago #
Olmeister
Member

Is it possible to tell with robodude666's code which body is being contacted? Via IF statements, similar to Ray Wenderlichs breakout tutorial?

Posted 10 months ago #
erichcl
Member

Hello,

I'm facing the same error as RENUKA (2 posts above), when trying to call the query:
world->QueryAABB(&callback, aabb);

The app simply quits.

Did you find what was going wrong? And a solution?
Thanks!

Posted 10 months ago #
purplelilgirl
Member

Sorry for reviving an old thread but I was wondering the same thing as mithril, can i limit the rotation of the mouse joint?

Posted 6 months ago #
iforce2d
Member
A revolute joint can control rotation limits. You can have a very light body (no fixture necessary) which is set to fixed rotation, and join this to the body the user moves.

If you don't give this body a fixture, it's mass will default to 1. Most likely you will need it lighter than that. You could either add a very low density fixture and set it as a sensor so it doesn't interfere with any collision, or explicitly set the mass after creating it like this:
```
b2MassData md;
body->GetMassData( &md );
md.mass = 0.0001;
body->SetMassData( &md );
```
Posted 6 months ago #

RSS feed for this topic

Reply

You must log in to post.